En una entrada anterior habíamos desarrollado un componente para el control de un motor DC mediante PWM. En esta ocasión, desarrollaremos un componente para generar la señal de control para un servomotor.

[wpdm_file id=11]

Control de un servomotor

Primero que nada, un servomotor no es más que un motor de corriente directa con una tarjeta electrónica adjunta para facilitar su control. Para dicho control es necesario generar un pulso como se muestra en la figura 1.

La duración o frecuencia del pulso determina la posición en la que se debe situar el motor. Cada servomotor tiene su propio rango de frecuencias, determinadas por el fabricante en la hoja de datos. Para la figura 1, los valores de la señal están entre 1 y 2 ms.

Diseño del control

La señal de control para el servomotor se compone de dos frecuencias:

• Frecuencia de actualización de 20ms.
• Ancho de pulso que controla la posición del servomotor, provista por el fabricante. Para este ejemplo, asumiremos que la frecuencia va de 0.5 a 2.5ms.

¿Cómo empezamos a desarrollar los dos divisores de frecuencia necesarios para esta señal? Primero que nada, es necesario encontrar el rango de operación:

\(rango = tiempo_{max} – tiempo_{min} = 2.5ms – 0.5ms = 2 ms\)

Ahora es necesario saber la resolución del servomotor, o cantidad de posiciones que puede tomar. Por lo tanto, la frecuencia mínima necesaria es:

\(f_{necesaria} = \left(\dfrac{rango}{resolucion}\right)^{-1}\)

Si nuestro servomotor puede tomar 128 posiciones, tenemos que:

\(f_{necesaria} = \left(\dfrac{2ms}{128}\right)^{-1} = \left(0.015625ms\right)^{-1} = 64 kHz\)

Por tanto, es necesario diseñar un divisor de frecuencia de 64 kHz (el cual se muestra en el listado 1). Siempre puedes consultar cómo hacer un divisor de frecuencia.

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;

entity clk64kHz is
    Port (
        entrada: in  STD_LOGIC;
        reset  : in  STD_LOGIC;
        salida : out STD_LOGIC
    );
end clk64kHz;

architecture Behavioral of clk64kHz is
    signal temporal: STD_LOGIC;
    signal contador: integer range 0 to 780 := 0;
begin
    divisor_frecuencia: process (reset, entrada) begin
        if (reset = '1') then
            temporal <= '0';
            contador <= 0;
        elsif rising_edge(entrada) then
            if (contador = 780) then
                temporal <= NOT(temporal);
                contador <= 0;
            else
                contador <= contador + 1;
            end if;
        end if;
    end process;

    salida <= temporal;
end Behavioral;

Finalmente, sabemos que con un reloj de 64 kHz tenemos 1ms cada 64 iteraciones. Para tener la frecuencia de 20 ms basta multiplicar 64 * 20, implementado con un contador de 0 a 1279.

Implementación en VHDL

Para la implementación en VHDL tenemos tres entradas: reloj de 64kHz, reset, y un vector que puede tomar valores de 0 a 127. La única salida es la señal de control para el servomotor. El listado 2 muestra el código completo del componente.

[wpdm_file id=10]

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;

entity servo_pwm is
	PORT (
		clk   : IN  STD_LOGIC;
		reset : IN  STD_LOGIC;
		pos   : IN  STD_LOGIC_VECTOR(6 downto 0);
		servo : OUT STD_LOGIC
	);
end servo_pwm;

architecture Behavioral of servo_pwm is
	-- Contador de 0 a 1279.
	signal cnt : unsigned(10 downto 0);
	-- Señal temporal para generar el PWM.
	signal pwmi: unsigned(7 downto 0);
begin
	-- Valor mínimo debe ser de 0.5ms.
	pwmi <= unsigned('0' & pos) + 32;
	-- Proceso del contador, de 0 a 1279.
	contador: process (reset, clk) begin
		if (reset = '1') then
			cnt <= (others => '0');
		elsif rising_edge(clk) then
			if (cnt = 1279) then
				cnt <= (others => '0');
			else
				cnt <= cnt + 1;
			end if;
		end if;
	end process;
	-- Señal de salida para el servomotor.
	servo <= '1' when (cnt < pwmi) else '0';
end Behavioral;

La señal cnt sirve para implementar el contador de 0 a 1279, mismo que se describe en el proceso de las líneas 22 a 33.

La señal de entrada pos es un vector con valores de 0 a 127, que dan el rango de 0ms a 2ms. Así que es necesario sumar un total de 32 a la señal para generar un pulso de 0.5ms a 2.5ms (línea 21). La señal de salida estará activa solamente cuando el valor de la señal pwmi sea menor que el valor del contador.

El listado 3 incluye el PORT MAP necesario para unir el divisor con el controlador del servomotor.

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;

entity servo_pwm_clk64kHz is
	PORT(
		clk  : IN  STD_LOGIC;
		reset: IN  STD_LOGIC;
		pos  : IN  STD_LOGIC_VECTOR(6 downto 0);
		servo: OUT STD_LOGIC
	);
end servo_pwm_clk64kHz;

architecture Behavioral of servo_pwm_clk64kHz is
	COMPONENT clk64kHz
		PORT(
			entrada: in  STD_LOGIC;
			reset  : in  STD_LOGIC;
			salida : out STD_LOGIC
		);
	END COMPONENT;

	COMPONENT servo_pwm
		PORT (
			clk   : IN  STD_LOGIC;
			reset : IN  STD_LOGIC;
			pos   : IN  STD_LOGIC_VECTOR(6 downto 0);
			servo : OUT STD_LOGIC
		);
	END COMPONENT;

	signal clk_out : STD_LOGIC := '0';
begin
	clk64kHz_map: clk64kHz PORT MAP(
		clk, reset, clk_out
	);

	servo_pwm_map: servo_pwm PORT MAP(
		clk_out, reset, pos, servo
	);
end Behavioral;

Simulación y banco de pruebas

Para el banco de pruebas se utilizaron diversos valores de entrada para pos, desde 0 a 127 (líneas 43 a 59).

LIBRARY ieee;
USE ieee.std_logic_1164.ALL;

ENTITY servo_pwm_clk64kHz_tb IS
END servo_pwm_clk64kHz_tb;

ARCHITECTURE behavior OF servo_pwm_clk64kHz_tb IS
	-- Unidad bajo prueba.
	COMPONENT servo_pwm_clk64kHz
		PORT(
			clk   : IN  std_logic;
			reset : IN  std_logic;
			pos   : IN  std_logic_vector(6 downto 0);
			servo : OUT std_logic
		);
	END COMPONENT;

	-- Entradas.
	signal clk  : std_logic := '0';
	signal reset: std_logic := '0';
	signal pos  : std_logic_vector(6 downto 0) := (others => '0');
	-- Salidas.
	signal servo : std_logic;
	-- Definición del reloj.
	constant clk_period : time := 20 ns;
BEGIN
	-- Instancia de la unidad bajo prueba.
	uut: servo_pwm_clk64kHz PORT MAP (
		clk => clk,
		reset => reset,
		pos => pos,
		servo => servo
	);

   -- Definición del proceso de reloj.
   clk_process :process begin
		clk <= '0';
		wait for clk_period/2;
		clk <= '1';
		wait for clk_period/2;
   end process;

	-- Procesamiento de estímulos.
	proceso_estimulos: process begin
		reset <= '1';
		wait for 50 ns;
		reset <= '0';
		wait for 50 ns;
		pos <= "0000000";
		wait for 20 ms;
		pos <= "0101000";
		wait for 20 ms;
		pos <= "1010000";
		wait for 20 ms;
		pos <= "1111000";
		wait for 20 ms;
		pos <= "1111111";
		wait;
	end process;
END;

El resultado de la simulación se muestra en la figura 2. Para la frecuencia de 20 ms se obtuvo una frecuencia de 19.9936 ms, para la frecuencia mínima se obtuvo 0.4920 ms y para la frecuencia máxima se obtuvo una frecuencia de 2.4835 ms.

El contenido de los cuatro listados se incluye en el siguiente enlace de descarga:

[wpdm_file id=11]

Aplicaciones

Ahora ya tenemos un componente para controlar un motor DC y un controlador para servomotores. Son componentes relativamente simples, pero podemos empezar a pensar en aplicaciones y un poco de róbotica, para el movimiento de brazos como el Lynx 6.

Compiling vhdl file "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" in Library work.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 57. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 59. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 65. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 67. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 69. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 71. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 73. Wait for statement unsupported.
ERROR:HDLParsers:1015 - "C:/Users/INTEL/Desktop/Nueva carpeta/servo/servo_pwm_clk64kHz_tb.vhd" Line 75. Wait for statement unsupported.

Process "Check Syntax" failed